周记 总结26年至今的成果

function chrome_with_cdp -a port app_name
    if test -z "$port"
        set port 9223
    end
    if test -z "$app_name"
        set app_name "iChrome"
    end

    set chrome_app '/Applications/Google Chrome.app'
    set app_dir /Applications/$app_name.app
    set contents_dir $app_dir/Contents
    set macos_dir $contents_dir/MacOS

    if not test -d "$app_dir"
        mkdir -p $macos_dir

        ln -sf $chrome_app/Contents/MacOS/'Google Chrome' $macos_dir/$app_name
        ln -sf $chrome_app/Contents/Frameworks $contents_dir/Frameworks
        cp -r $chrome_app/Contents/Resources $contents_dir/Resources
        cp $DOTFILES/assets/ichrome/ichrome.icns $contents_dir/Resources/app.icns
    end

    if not test -f $contents_dir/Info.plist
        printf '<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
    <key>CFBundleExecutable</key>
    <string>%s</string>
    <key>CFBundleIconFile</key>
    <string>app.icns</string>
    <key>CFBundleIdentifier</key>
    <string>com.garden.%s</string>
    <key>CFBundleName</key>
    <string>%s</string>
    <key>CFBundlePackageType</key>
    <string>APPL</string>
    <key>CFBundleShortVersionString</key>
    <string>1.0</string>
    <key>CFBundleVersion</key>
    <string>1</string>
    <key>LSMinimumSystemVersion</key>
    <string>10.15</string>
</dict>
</plist>' $app_name $app_name $app_name > $contents_dir/Info.plist
    end

    set lsregister /System/Library/Frameworks/CoreServices.framework/Frameworks/LaunchServices.framework/Support/lsregister
    $lsregister -f $app_dir
    touch $app_dir

    open $app_dir --args \
        --no-first-run \
        --no-default-browser-check \
        --disable-session-crashed-bubble \
        --remote-debugging-port=$port \
        --user-data-dir=$DL/$app_name-CDP-$port
end